Subtotal Sample Source

class 를 이용한 ALV 가 많이 사용되고 있다.
아래는 http://www.sdn.sap.com 에서 찾은 subtotal sample source 다..

SUBTOTAL 을 위해서는 BUILD_SORT_CAT 구성시에 아래와 같은 구문을 넣어야 한다.
ls_sort-subtot    = abap_true.  " subtotal

*&---------------------------------------------------------------------*
*& Report  ZUS_SDN_ALV_SUBTOTAL
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*
 
REPORT  zus_sdn_alv_subtotal.
 
 
TYPE-POOLS: abap.
 
 
CONSTANTS:
  gc_table         TYPE tabname  VALUE 'VBAK'.
 
DATA:
  gd_okcode        TYPE ui_func,
*
  gt_sort          TYPE lvc_t_sort,
  gt_fcat          TYPE lvc_t_fcat,
  go_docking       TYPE REF TO cl_gui_docking_container,
  go_grid1         TYPE REF TO cl_gui_alv_grid.
 
 
DATA:
  gt_outtab        TYPE STANDARD TABLE OF vbak.
 
 
PARAMETERS:
  p_vkorg      TYPE vkorg  DEFAULT '3000'  OBLIGATORY.
 
 
START-OF-SELECTION.
 
  SELECT * FROM (gc_table) INTO TABLE gt_outtab
         WHERE  vkorg = p_vkorg.
 
 
 
* Create docking container
  CREATE OBJECT go_docking
    EXPORTING
      parent                      = cl_gui_container=>screen0
      ratio                       = 90
    EXCEPTIONS
      OTHERS                      = 6.
  IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
 
 
* Create ALV grid
  CREATE OBJECT go_grid1
    EXPORTING
      i_parent          = go_docking
    EXCEPTIONS
      OTHERS            = 5.
  IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
 
 
 
 
* Build fieldcatalog
  PERFORM build_fieldcatalog.
 
* Build sorting table
  PERFORM build_sort_criteria.
 
* Display data
  CALL METHOD go_grid1->set_table_for_first_display
    CHANGING
      it_outtab       = gt_outtab
      it_fieldcatalog = gt_fcat
      it_sort         = gt_sort
    EXCEPTIONS
      OTHERS          = 4.
  IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
 
 
 
 
* Link the docking container to the target dynpro
  CALL METHOD go_docking->link
    EXPORTING
      repid                       = syst-repid
      dynnr                       = '0100'
*      CONTAINER                   =
    EXCEPTIONS
      OTHERS                      = 4.
  IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
 
 
* ok-code field = GD_OKCODE
  CALL SCREEN '0100'.
 
 
END-OF-SELECTION.
 
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
  SET PF-STATUS 'STATUS_0100'.
*  SET TITLEBAR 'xxx'.
 
 
ENDMODULE.                 " STATUS_0100  OUTPUT
 
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
 
  CASE gd_okcode.
    WHEN 'BACK' OR
         'END'  OR
         'CANC'.
      SET SCREEN 0. LEAVE SCREEN.
 
 
    WHEN OTHERS.
  ENDCASE.
 
  CLEAR: gd_okcode.
 
ENDMODULE.                 " USER_COMMAND_0100  INPUT
 
 
*&---------------------------------------------------------------------*
*&      Form  BUILD_FIELDCATALOG
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM build_fieldcatalog.
* define local data
  DATA:
    ls_fcat        TYPE lvc_s_fcat.
 
  REFRESH: gt_fcat.
  CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
*     I_BUFFER_ACTIVE              =
      i_structure_name             = gc_table
*     I_CLIENT_NEVER_DISPLAY       = 'X'
*     I_BYPASSING_BUFFER           =
*     I_INTERNAL_TABNAME           =
    CHANGING
      ct_fieldcat                  = gt_fcat
    EXCEPTIONS
      inconsistent_interface       = 1
      program_error                = 2
      OTHERS                       = 3.
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
 
  DELETE gt_fcat WHERE NOT ( fieldname = 'VBELN'  OR
                             fieldname = 'VKORG'  OR
                             fieldname = 'VTWEG'  OR
                             fieldname = 'SPART'  OR
                             fieldname = 'NETWR' ).
  LOOP AT gt_fcat INTO ls_fcat
          WHERE ( fieldname = 'NETWR' ).
    ls_fcat-do_sum = abap_true. " sum up column values
 
    MODIFY gt_fcat FROM ls_fcat.
  ENDLOOP.
 
 
 
ENDFORM.                    " BUILD_FIELDCATALOG
 
 
*&---------------------------------------------------------------------*
*&      Form  BUILD_SORT_CRITERIA
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM build_sort_criteria .
* define local data
  DATA:
    ls_sort    TYPE lvc_s_sort.
 
  REFRESH: gt_sort.
 
  CLEAR: ls_sort.
  ls_sort-spos = '1'.
  ls_sort-fieldname = 'VTWEG'.
  ls_sort-up        = abap_true.
  ls_sort-subtot    = abap_true.
  APPEND ls_sort TO gt_sort.
*
  CLEAR: ls_sort.
  ls_sort-spos = '2'.
  ls_sort-fieldname = 'SPART'.
  ls_sort-up        = abap_true.
  ls_sort-subtot    = abap_true.  " subtotal
  APPEND ls_sort TO gt_sort.
ENDFORM.                    " BUILD_SORT_CRITERIA